SICP 問題 2.83（一階層上位の型への汎用強制型変換手続きraise）

問題

図2.25に示した型の塔： 整数、有理数、実数、複素数を扱う汎用算術演算システムを設計しているとしよう。（複素数を除く）各型について、その型のオブジェクトを塔の中で一レベル高める手続きを設計せよ。（複素数を除く）各型に働く汎用raise演算はどう設計するか。

解答

この問題ものすごーく考え込んだんだけど、「パッケージ同士の依存関係」をはっきりさせる必要が出てくるんじゃなかろうか。（ホントはそんなに難しく考える必要ないのかもしれないけど。。）
「基本的な型（整数型）→汎用型（複素数）」こんな感じ？

integer

↓（型変換するなら依存）

rational

↓（型変換するなら依存）

real

↓（型変換するなら依存）

complex

この前提で改めてファイルを分割してコードを組み立てるとこんな感じ？あ、コード自体は、

scheme-number

↓（型変換するなら依存）

rational

↓（型変換するなら依存）

real

↓（型変換するなら依存）

complex

にしてあります。

calcurate-system.scm

まずは汎用演算システムのコア部分。

;;;==============================
;;;汎用演算定義
;;;==============================

;hashtableのパッケージもロードしておいちゃう。
(load "./sicp-hashtable.scm")


;演算パッケージで扱う基本的データ型
(load "./calcurate-scheme-number.scm")


(define (apply-generic op . args)
  (let* ((type-tags (map type-tag args))
	 (proc (get op type-tags)))
    (if proc
	(apply proc (map contents args))
	(error
	 "No method for these types -- APPLY-GENERIC"
	 (list op type-tags)))))

(define (attach-tag type-tag contents)
  (if (eq? type-tag 'scheme-number)
      contents
      (cons type-tag contents)))

(define (type-tag datum)
  (cond ((pair? datum)
	 (car datum))
	((number? datum)
	 'scheme-number)
	(else
	 (error "Bad tagged datum -- TYPE-TAG" datum))))

(define (contents datum)
  (cond ((pair? datum)
	 (cdr datum))
	((number? datum)
	 datum)))

(define (add x y) (apply-generic 'add x y))
(define (sub x y) (apply-generic 'sub x y))
(define (mul x y) (apply-generic 'mul x y))
(define (div x y) (apply-generic 'div x y))
(define (equ? x y) (apply-generic 'equ? x y))
(define (=zero? x) (apply-generic '=zero? x))

;;１レベル高める汎用手続き
(define (raise x) (apply-generic 'raise x))

calcurate-scheme-number.scm

;;;==============================
;;;scheme-number演算パッケージ
;;;==============================


;;強制型変換を可能にする為、rationalパッケージをロードする。
(load "./calcurate-rational.scm")


(define (install-scheme-number-package)
  (define (tag x)
    (attach-tag 'scheme-number x))
  (put 'add '(scheme-number scheme-number)
       (lambda (x y) (tag (+ x y))))
  (put 'sub '(scheme-number scheme-number)
       (lambda (x y) (tag (- x y))))
  (put 'mul '(scheme-number scheme-number)
       (lambda (x y) (tag (* x y))))
  (put 'div '(scheme-number scheme-number)
       (lambda (x y) (tag (/ x y))))
  (put 'make 'scheme-number
       (lambda (x) (tag x)))
  (put 'equ? '(scheme-number scheme-number)
       (lambda (x y) (eq? x y)))
  (put '=zero? '(scheme-number)
       (lambda (x) (eq? 0 (contents x))))

  ;;;有理数への強制型変換
  (put 'raise '(scheme-number)
       (lambda (x)
	 (make-rational (contents x) 1)))

  'done)
(install-scheme-number-package)

(define (make-scheme-number n)
  ((get 'make 'scheme-number) n))

calcurate-rational.scm

;;;==============================
;;;rational演算パッケージ
;;;==============================


;;強制型変換を可能にする為、realパッケージをロードする。
(load "./calcurate-real.scm")


(define (install-rational-package)
  (define (gcd a b)
    (if (= b 0)
	a
	(gcd b (remainder a b))))
  (define (numer x) (car x))
  (define (denom x) (cdr x))
  (define (make-rat n d)
    (let ((g (gcd n d)))
      (cons (/ n g) (/ d g))))
  (define (add-rat x y)
    (make-rat (+ (* (numer x) (denom y))
		 (* (numer y) (denom x)))
	      (* (denom x) (denom y))))
  (define (sub-rat x y)
    (make-rat (- (* (numer x) (denom y))
		 (* (numer y) (denom x)))
	      (* (denom x) (denom y))))
  (define (mul-rat x y)
    (make-rat (* (numer x) (numer y))
	      (* (denom x) (denom y))))
  (define (div-rat x y)
    (make-rat (* (numer x) (denom y))
	      (* (denom x) (numer y))))
  (define (tag x)
    (attach-tag 'rational x))

  (put 'add '(rational rational)
       (lambda (x y) (tag (add-rat x y))))
  (put 'sub '(rational rational)
       (lambda (x y) (tag (sub-rat x y))))
  (put 'mul '(rational rational)
       (lambda (x y) (tag (mul-rat x y))))
  (put 'div '(rational rational)
       (lambda (x y) (tag (div-rat x y))))
  (put 'make 'rational
       (lambda (n d) (tag (make-rat n d))))
  (put 'equ? '(rational rational)
       (lambda (x y) (equal? x y)))
  (put '=zero? '(rational)
       (lambda (x)
	 (eq? 0 (numer x))))

  ;;;複素数への強制型変換
  (put 'raise '(rational)
       (lambda (x)
	 (make-real (/ (numer x) (denom x)))))
  'done)
(install-rational-package)

(define (make-rational n d)
  ((get 'make 'rational) n d))

calcurate-real.scm

;;;==============================
;;;real演算パッケージ
;;;==============================


;;強制型変換を可能にする為、complexパッケージをロードする。
(load "./calcurate-complex.scm")


(define (install-real-package)
  (define (tag x)
    (attach-tag 'real x))
  (put 'add '(real real)
       (lambda (x y) (tag (+ x y))))
  (put 'sub '(real real)
       (lambda (x y) (tag (- x y))))
  (put 'mul '(real real)
       (lambda (x y) (tag (* x y))))
  (put 'div '(real real)
       (lambda (x y) (tag (/ x y))))
  (put 'make 'real
       (lambda (x) (tag x)))
  (put 'equ? '(real real)
       (lambda (x y) (eq? x y)))
  (put '=zero? '(real)
       (lambda (x) (eq? 0 (contents x))))

  ;;;複素数への強制型変換
  (put 'raise '(real)
       (lambda (x)
	 (make-complex-from-real-imag (contents x) 0)))

  'done)
(install-real-package)

(define (make-real n)
  ((get 'make 'real) n))

calcurate-complex.scm

;;;==============================
;;;complexパッケージ
;;;==============================


;;サブパッケージに依存しているのでロード
(load "./calcurate-complex-rectanglar.scm")
(load "./calcurate-complex-polar.scm")


(define (install-complex-package)
  (define (make-from-real-imag x y)
    ((get 'make-from-real-imag 'rectangular) x y))
  (define (make-from-mag-ang r a)
    ((get 'make-from-mag-ang 'polar) r a))
  (define (add-complex z1 z2)
    (make-from-real-imag (+ (real-part z1) (real-part z2))
			 (+ (imag-part z1) (imag-part z2))))
  (define (sub-complex z1 z2)
    (make-from-real-imag (- (real-part z1) (real-part z2))
			 (- (imag-part z1) (imag-part z2))))
  (define (mul-complex z1 z2)
    (make-from-mag-ang (* (magunitude z1) (magunitude z2))
		       (+ (angle z1) (angle z2))))
  (define (div-complex z1 z2)
    (make-from-mag-ang (/ (magunitude z1) (magunitude z2))
		       (- (angle z1) (angle z2))))
  (define (real-part z)
    (apply-generic 'real-part z))
  (define (imag-part z)
    (apply-generic 'imag-part z))
  (define (magnitude z)
    (apply-generic 'magnitude z))
  (define (angle z)
    (apply-generic 'angle z))
  (define (tag z) (attach-tag 'complex z))
  
  (put 'add '(complex complex)
       (lambda (z1 z2) (tag (add-complex z1 z2))))
  (put 'sub '(complex complex)
       (lambda (z1 z2) (tag (sub-complex z1 z2))))
  (put 'mul '(complex complex)
       (lambda (z1 z2) (tag (mul-complex z1 z2))))
  (put 'div '(complex complex)
       (lambda (z1 z2) (tag (div-complex z1 z2))))
  (put 'make-from-real-imag 'complex
       (lambda (x y) (tag (make-from-real-imag x y))))
  (put 'make-from-mag-ang 'complex
       (lambda (r a) (tag (make-from-mag-ang r a))))
  (put 'real-part '(complex) real-part)
  (put 'imag-part '(complex) imag-part)
  (put 'magnitude '(complex) magnitude)
  (put 'angle '(complex) angle)
  (put 'equ? '(complex complex)
       (lambda (x y) (equal? x y)))
  (put '=zero? '(complex)
       (lambda (x)
	 (apply-generic '=zero? x)))
  'done)
(install-complex-package)

(define (make-complex-from-real-imag x y)
  ((get 'make-from-real-imag 'complex) #?=x #?=y))
(define (make-complex-from-mag-ang r a)
  ((get 'make-from-mag-ang 'complex) r a))

(define (real-part z) (apply-generic 'real-part z))
(define (imag-part z) (apply-generic 'imag-part z))
(define (magnitude z) (apply-generic 'magnitude z))
(define (angle z) (apply-generic 'angle z))

calcurate-complex-rectanglar.scm

;;;==============================
;;;complex（rectangular）サブパッケージ
;;;==============================
(define (install-rectangular-package)
  (define (square x) (* x x))
  (define (real-part z) (car z))
  (define (imag-part z) (cdr z))
  (define (make-from-real-imag x y) (cons x y))
  (define (magnitude z)
    (sqrt (+ (square (real-part z))
	     (square (imag-part z)))))
  (define (angle z)
    (atan (imag-part z) (real-part z)))
  (define (make-from-mag-ang r a)
    (cons (* r (cos a)) (* r (sin a))))
  (define (tag x) (attach-tag 'rectangular x))

  (put 'real-part '(rectangular) real-part)
  (put 'imag-part '(rectangular) imag-part)
  (put 'magnitude '(rectangular) magnitude)
  (put 'angle '(rectangular) angle)
  (put 'make-from-real-imag 'rectangular
       (lambda (x y) (tag (make-from-real-imag x y))))
  (put 'make-from-mag-ang 'rectangular
       (lambda (r a) (tag (make-from-mag-ang r a))))
  (put 'equ? '(rectangular rectangular)
       (lambda (x y) (equal? x y)))
  (put '=zero? '(rectangular)
       (lambda (x)
	 (and (eq? 0 (real-part x))
	      (eq? 0 (imag-part x)))))
  'done)
(install-rectangular-package)

||



***calcurate-complex-polar.scm
>|scheme|
;;;==============================
;;;complex（polar）サブパッケージ
;;;==============================
(define (install-polar-package)
  (define (square x) (* x x))
  (define (magnitude z) (car z))
  (define (angle z) (cdr z))
  (define (make-from-mag-ang r a) (cons r a))
  (define (real-part z)
    (* (magnitude z) (cos (angle z))))
  (define (imag-part z)
    (* (magnitude z) (sin (angle z))))
  (define (make-from-real-imag x y)
    (cons (sqrt (+ (square x) (square y)))
	  (atan y x)))
  (define (tag x) (attach-tag 'polar x))

  (put 'real-part '(polar) real-part)
  (put 'imag-part '(polar) imag-part)
  (put 'magnitude '(polar) magnitude)
  (put 'angle '(polar) angle)
  (put 'make-from-real-imag 'polar
       (lambda (x y) (tag (make-from-real-imag x y))))
  (put 'make-from-mag-ang 'polar
       (lambda (r a) (tag (make-from-mag-ang r a))))
  (put 'equ? '(polar polar)
       (lambda (x y) (equal? x y)))
  (put '=zero? '(polar)
       (lambda (x)
	 (and (eq? 0 (magnitude x))
	      (eq? 0 (angle x)))))
  'done)
(install-polar-package)

各ファイルは、依存するファイルをロードするようにしてある。では実験。

gosh> (define s 3)

s

gosh> s

3

gosh> (raise s)

(rational 3 . 1)

gosh> (raise (raise s))

(real . 3)

gosh> (raise (raise (raise s)))

(complex rectangular 3 . 0)

gosh> (define ra (make-rational 1 3))

ra

gosh> ra

(rational 1 . 3)

gosh> (raise ra)

(real . 1/3)

gosh> (raise (raise ra))

(complex rectangular 1/3 . 0)

gosh> (define re (make-real 3.1415))

re

gosh> re

(real . 3.1415)

gosh> (raise re)

(complex rectangular 3.1415 . 0)

gosh> 

やっとできた。。長かった。。

てかこのセクションつまんねー！！早く３章行きてーっ！！